home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Transactor
/
Transactor_03_1985_Transactor_Publishing.d64
/
home budget
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2023-02-26
|
4KB
|
151 lines
0 rem the transactor volume 5 issue 04 page 46
1 rem this version modified from the listing printed
100 rem*********************
110 rem* *
120 rem* home budget *
130 rem* by *
140 rem* brian dobbs *
150 rem* *
160 rem* timmins,ontario *
170 rem* *
180 rem*********************
190 poke53280,11:poke53281,0:dima$(13,13),dt$(12):print""
200 for i=1to12:read dt$(i):next i
210 goto290
220 gosub1420: if kk then 290
230 open14,8,14,"0:"+nm$+",s,r"
240 for x=1 to 13
250 for y=2 to 13: input#14,a$(x,y)
260 next y,x
270 close14
280 :
290 print"[147]"tab(14)"budget menu"
300 printtab(14)"[183][183][183][183][183][183][183][183][183][183][183]"
310 printtab(10)"1[146]-write monthly bills":print""
320 printtab(10)"2[146]-view monthly bills":print""
330 printtab(10)"3[146]-barchart trend of bills":print""
340 printtab(10)"4[146]-printer trend of bills":print""
350 printtab(10)"5[146]-save data to disk":print""
360 printtab(10)"6[146]-load data from disk":print""
370 printtab(10)"7[146]-create initial file":print""
380 printtab(10)"select choice (1-7)":y=0
390 getan$:ifan$=""then390
400 forx=1to7:ifan$=mid$("1234567",x,1)theny=x
410 next:onygoto550,420,660,940,1180,220,1220:goto290
420 print"[147]":gosub1270
430 input"enter month to view (0=menu)";x
440 if x=0 then 290
450 x=x+1
460 print"[147]"
470 fory=2to13:print a$(1,y):next y
480 print"[145][145][145][145][145][145][145][145][145][145][145][145][145]"
490 fory=2to13:printtab(15)a$(x,y):nexty
500 gosub1500
510 print"monthly total"tab(14)q+aa+bb
520 geta$:ifa$=""then520
530 goto420
540 :
550 print"[147]":gosub1270
560 input"what month to write bills (0=menu)";x
570 if x=0 then 290
580 x=x+1:print"[147]"
590 printtab(15)dt$(x-1)""
600 for y=2 to 13:printa$(1,y):next y
610 print"[145][145][145][145][145][145][145][145][145][145][145][145][145]"
620 fory=2to13:printtab(15):inputa$(x,y)
630 next y
640 goto 550
650 :
660 print"[147]"
670 for p=2to13
680 print""p-1"[146])"a$(1,p)
690 next p
700 input"enter number of desired bill";y:y=y+1
710 print"what is maximum scale for "a$(1,y);:input b
720 print"[147]":printtab(20-(len(a$(1,y))/2))a$(1,y)
730 print""b:z=0
740 z=z+(b/20):ifz=bthen760
750 printint(b-z):goto740
760 r=1992:x=2:t=56264:u=2
770 fore=rtor-(40*((val(a$(x,y))/(b/20))))step-40
780 ife>1023ande<2024thenpokee,224
790 next
800 forf=ttot-(40*((val(a$(x,y))/(b/20))))step-40
810 iff>55295andf<56296thenpokef,u
820 next
830 r=r+2:x=x+1:t=t+2:u=u+1
840 ifu=3thenu=1
850 ifx=14then870
860 goto770
870 r=1992:t=56264:poker,138:poket,1:poker+2,134:poket+2,1:poker+4,141
880 poket+4,1:poker+6,129:poket+6,1:poker+8,141:poket+8,1:poker+10,138
890 poket+10,1:poker+12,138:poket+12,1:poker+14,129:poket+14,1:poker+16,147
900 poket+16,1:poker+18,143:poket+18,1:poker+20,142:poket+20,1:poker+22,132
910 poket+22,1
920 geta$:ifa$=""then920
930 goto290
940 open4,4:print#4,tab(38)"budget 1984":print#4:l=2:m=7
950 print#4," bill ";
960 print#4,"january febuary march april may june"
970 gosub1060
980 l=2:m=7
990 gosub1100
1000 l=8:m=13:print#4," bill ";
1010 print#4,"july august september october november december"
1020 gosub1060
1030 l=8:m=13
1040 gosub1100
1050 close4:restore:goto290
1060 fory=1to13:z=20-len(a$(1,y))
1070 print#4,a$(1,y)tab(z);
1080 fori=ltom:print#4,(a$(i,y))tab(10-len(a$(i,y)));:nexti:print#4,chr$(10)
1090 nexty:print#4:return
1100 print#4,"monthly total"tab(6)
1110 forx=ltom
1120 gosub1500
1130 c=q+aa+bb:c$=str$(c)
1140 print#4,q+aa+bbtab(9-len(c$));:nextx
1150 print#4,chr$(10)
1160 return
1170 :
1180 gosub1420: if kk then 290
1190 open14,8,14,"@0:"+nm$+",s,w"
1200 goto 1380
1210 :
1220 print"[147] a total of 12 bills will be entered.": xx=fre(0)
1230 for y=2 to 13
1240 print"name of bill";y-1;:input a$(1,y)
1250 next y: goto1320
1260 :
1270 for w=1to12
1280 print""w"[146])"dt$(w)
1290 next w
1300 return
1310 :
1320 print"[147]"
1330 for x=2to13:for y=2to13
1340 a$(x,y)="0": next y,x: xx=fre(0)
1350 gosub 1420 'get filename
1360 open14,8,14,"0:"+nm$+",s,w"
1370 print" creating initial file[146]"
1380 for x=1to 12: for y=2 to 13
1390 print#14,a$(x,y): next y,x
1400 close14:goto290
1410 :
1420 input"[147] filename[146]";nm$
1430 print" press 'f1[146]' to continue"
1440 geta$:ifa$=""then1440
1450 kk=(a$<>chr$(133)):rem f1 key
1460 return
1470 :
1480 data january,february,march,april,may,june,july,august,september,october
1490 data november,december
1500 q=(val(a$(x,2)))+(val(a$(x,3)))+(val(a$(x,4)))+(val(a$(x,5)))
1510 aa=(val(a$(x,6)))+(val(a$(x,7)))+(val(a$(x,8)))+(val(a$(x,9)))
1520 bb=(val(a$(x,10)))+(val(a$(x,11)))+(val(a$(x,12)))+(val(a$(x,13)))
1530 return
1540 :
1550 fori=1to12
1560 print""i"[146])"a$(1,i)
1570 next i: return